      SUBROUTINE SSCAL( N, SA, SX, INCX )
*
*     scales a vector by a constant.
*     uses unrolled loops for increment equal to 1.
*     jack dongarra, linpack, 3/11/78.
*
*     .. Scalar Arguments ..
      INTEGER           INCX, N
      REAL              SA
*     ..
*     .. Array Arguments ..
      REAL              SX( 1 )
*     ..
*     .. Local Scalars ..
      INTEGER           I, IX, M, MP1, NINCX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC         MOD
*     ..
*     .. Executable Statements ..
*
      IF( N.LE.0 )
     $   RETURN
      IF( INCX.EQ.1 )
     $   GO TO 20
*
*        code for increment not equal to 1
*
      IX = 1
      IF( INCX.LT.0 )
     $   IX = 1 - ( N-1 )*INCX
      NINCX = IX + ( N-1 )*INCX
      DO 10 I = IX, NINCX, INCX
         SX( I ) = SA*SX( I )
   10 CONTINUE
      RETURN
*
*        code for increment equal to 1
*
*
*        clean-up loop
*
   20 M = MOD( N, 5 )
      IF( M.EQ.0 )
     $   GO TO 40
      DO 30 I = 1, M
         SX( I ) = SA*SX( I )
   30 CONTINUE
      IF( N.LT.5 )
     $   RETURN
   40 MP1 = M + 1
      DO 50 I = MP1, N, 5
         SX( I ) = SA*SX( I )
         SX( I+1 ) = SA*SX( I+1 )
         SX( I+2 ) = SA*SX( I+2 )
         SX( I+3 ) = SA*SX( I+3 )
         SX( I+4 ) = SA*SX( I+4 )
   50 CONTINUE
      RETURN
      END
